on 1:action:*:#:{
  if ( $findtok($strip($1-),$me,32) != $null ) && ( slap isin $strip($1-) ) {
    if ( %slapignore [ $+ [ $address($nick,3) ] ] == 1 ) {
      /.notice $nick Du bist jetzt auf Slapignore für einige Minuten!! :)
      //Echo -s *** Added $nick to Slapignore for some time!
      /set -u300 %slapignore [ $+ [ $address($nick,3) ] ]  2 
      halt
    } 
    if ( %slapignore [ $+ [ $address($nick,3) ] ] == 2 ) {
      /.notice $nick Du bist jetzt, weil du ein Powerslapper bist, auf Slapignore bis mein mIRC neu startet!! :)
      //Echo -s *** Added Powerslapper $nick to Slapignore until mIRC restart!
      /set %slapignore [ $+ [ $address($nick,3) ] ]  3 
      halt
    }   
    if ( %slapignore [ $+ [ $address($nick,3) ] ] == 3 ) {
      halt
    }       
    /set -u300 %slapignore [ $+ [ $address($nick,3) ] ]  1
    var %line = 1
    var %size = $slapsize
    if ( %size > 0 ) {
      while ( %line <= %size ) {
        if ( $address($nick,3) == $slaphost(%line)) {
          /hadd slapdata %line $calc( $slapcounter(%line) + 1 ) $+ § $+ $slaphost(%line) $+ § $+ $slapnick(%line) 
          if ( %lastslapper == $nick ) {
            msg $chan Also wirklich $nick $+ ! Du hast mich schon zuletzt geslappt und bleibst deswegen auf dem Scheiterhaufen als $slapcount $+ . Slapper :þ       
          }         
          elseif ( %slaprevenge != $null ) {
            msg $chan Ich wurde doch grade geslappt! Du bist nun auch auf dem Scheiterhaufen und gesellst Dich zu %lastslapper $+ ! :þ
          } 
          else {
            msg $chan Also wirklich $nick $+ ! Du bist der $slapcount $+ . Ketzer der mich schlägt! Du wirst diese Schandtat wie %lastslapper auf dem Scheiterhaufen bereuen!
          }
          /set -g %lastslapper $nick      
          /set -u30 %slaprevenge 1
          /savetable
          halt
        }
        /inc %line
      }
      if ( %line > %size ) {
        /hadd slapdata %line 1 $+ § $+ $address($nick,3) $+ § $+ $nick 
        if ( %slaprevenge != $null ) {
          msg $chan Ich wurde doch grade geslappt! Du bist nun auch auf dem Scheiterhaufen und gesellst Dich zu %lastslapper $+ ! :þ
        } 
        else {
          msg $chan Also wirklich $nick $+ ! Du bist der $slapcount $+ . Ketzer der mich schlägt! Du wirst diese Schandtat wie %lastslapper auf dem Scheiterhaufen bereuen!
        }
        /set -g %lastslapper $nick      
        /set -u30 %slaprevenge 1
        /savetable
        halt      
      }
    }
    else {
      /hadd slapdata 1 1 $+ § $+ $address($nick,3) $+ § $+ $nick
      msg $chan Also wirklich $nick $+ ! Du bist der Erste Ketzer der mich schlägt! Du wirst diese Schandtat auf dem Scheiterhaufen bereuen!
      /set -g %lastslapper $nick      
      /set -u30 %slaprevenge 1
      /savetable
    }
  }
}

on *:start:{
  unset %slapignore*
  loadslapstable
}

alias -l savetable {
  if ($ini(slaps_new.ini,slaps,0) != $null) {
    /remini slaps_new.ini slaps
  }
  /hsave -i slapdata slaps_new.ini slaps
  if ($ini(slaps_new.ini,slaps,0) != $null) {
    /set %slapini $ini(slaps_new.ini,slaps,0)
  }
  else {
    /unset %slapini 
  }  
}

on 1:text:!myslapstats:#:{
  slapstats $nick
}

on 1:text:!slapstats*:#:{
  if ( $2 != $null ) {
    slapstatschan $2
  } 
  else {
    top5
  }
}

alias -l loadslapstable {
  if ($hget(slapdata)) {
    hfree slapdata
  }
  if ($ini(slaps_new.ini,slaps,0) != $null) {
    /set %slapini $ini(slaps_new.ini,slaps,0)
  } 
  else {
    /unset %slapini
  }
  hmake slapdata $iif(%slapini,%slapini,1)
  hload -ib slapdata slaps_new.ini slaps
  savetable
}

alias conslap {
  var %line 9
  var %ttssnum 1
  while ( $read(ats.ats,%line) != $null ) {
    var %ttss 1
    while ( %ttss <= $numtok($read(ats.ats,%line),32) ) {
      if ( $gettok($gettok($read(ats.ats,%line),%ttss,32),3,$asc(§)) != $null ) {
        /writeini slaps_new.ini slaps %ttssnum $gettok($read(ats.ats,%line),%ttss,32)
      }
      /inc %ttss
      /inc %ttssnum
    }
    /inc %line
  }
}

alias -l slapcount {
  var %slapcount = 0
  var %i = 1
  while ( %i <= $slapsize  ) {
    %slapcount = $calc( %slapcount + $slapcounter(%i) )
    /inc %i
  }
  return %slapcount
}

alias -l dirlines {
  return $iif(%slapini,%slapini,0)
}

alias -l slapsize {
  return $dirlines()

}
alias -l slapdata {
  var %position = $1
  var %slap = $hget(slapdata,%position)
  return %slap
}

alias -l slaphost {
  var %slap = $gettok($slapdata($1),2,$asc(§))
  return %slap
}

alias -l slapcounter {
  var %slap = $gettok($slapdata($1),1,$asc(§))
  return %slap
}

alias -l slapcounterini {
  var %slap = $gettok($readini(slaps_new.ini,slaps,$1),1,$asc(§))
  //echo -at %slap
  return %slap
}

alias -l slapnick {
  var %slap = $gettok($slapdata($1),3,$asc(§))
  return %slap
}

alias -l slapaddress {
  var %line = $hfind(slapdata, $2 $+ § $+ $1 $+ §* ,1,w).data
  var %hosts = $slaphost(%line)
  var %count = $slapcounter(%line)
  if (( %hosts == $1 ) && ( %count == $2 )) {
    return %line
  }
  return 0
}

alias -l slapnicks {
  var %line = $hfind(slapdata, $2 $+ *§ $+ $1 ,1,w).data
  var %nick = $slapnick(%line)
  var %count = $slapcounter(%line)
  if (( %nick == $1 ) && ( %count == $2 )) {
    return %line
  }
  return $null
}

alias slapstats {
  window -h @slaps | var %i 1
  while ( %i <= $slapsize ) {
    aline @slaps $slapcounter(%i)
    inc %i
  }
  filter -cetuww 2 32 @slaps @slaps
  var %i 1 | while %i <= $slapsize {
    var %count = $line(@slaps,%i)
    var %hosts = $slapaddress($address($1,3),%count)   
    if ( %hosts != 0 ) {
      .notice $1 Du bist auf Platz %i mit $slapcounter(%hosts) Slaps!
      window -c @slaps        
      halt
    }
    inc %i
  }
  .notice $1 Ich wurde bisher noch nicht von Dir geslappt!
  window -c @slaps
}

alias slapstatschan {
  window -h @slaps | var %i 1
  while ( %i <= $slapsize ) {
    aline @slaps $slapcounter(%i)
    inc %i
  }
  filter -cetuww 2 32 @slaps @slaps
  var %i 1 | while %i <= $slapsize {
    var %count = $line(@slaps,%i)
    var %hosts = $slapaddress($address($1,3),%count)    
    if ( %hosts != 0 ) {
      msg # Der Chatter $1 ist auf Platz %i mit $slapcounter(%hosts) Slaps!
      window -c @slaps        
      halt
    }
    var %nick = $slapnicks($1,%count)   
    if ( %nick ) {
      msg # Der nicht anwesende Chatter $1 ist auf Platz %i mit $slapcounter(%nick) Slaps!
      window -c @slaps        
      halt
    }    
    inc %i
  }
  msg # Der Chatter $1 hat bisher mich noch nicht geslappt!
  window -c @slaps
}

alias top5 {
  window -h @slaps  | var %i 1
  while %i <= $slapsize {
    aline @slaps $slapcounter(%i)
    inc %i
  }
  filter -cetuww 2 32 @slaps @slaps
  var %size = 5
  if ( $slapsize < 5 ) {
    %size = $slapsize
  }
  if ( $slapsize == 0 ) {
    var %list Bisher hat mich noch keiner geslappt!
  }  
  else {
    var %i 1 | while %i <= %size {
      var %line 1
      while ( %line <= $slapsize ) {
        var %count $line(@slaps,%i)
        if (%count == $slapcounter(%line)) {
          var %list %list $slapnick(%line) mit $slapcounter(%line) Slaps
          if (%i != %size) {
            var %list %list $+ $chr(44) $+ $chr(32)
          }
        }
        inc %line  
      }
      inc %i
    }
  }
  msg # Top 5 Slapper: %list $+ ! Insgesamt haben $slapsize Chatter mit $slapcount Slaps mich geslappt! !myslapstats für Stats! :)
  window -c @slaps
}